您可以声明一个数组以处理一组相同数据类型的值。 数组是具有多个可存储值的隔离舱的单个变量，而典型的变量只有一个存储隔离舱，其中只能存储一个值。 您可以在需要引用数组中包含的所有值时将数组作为整体引用，也可以引用其中的单个元素。
例如，若要存储一年中每天的日常开支，您可以声明一个具有 365 个元素的数组变量，而不是声明 365 个变量。 数组中的每个元素包含一个值。 以下语句声明具有 365 个元素的数组变量。 默认情况下，数组的索引从零开始，因此该数组的上限是 364 而不是 365。
Dim curExpense(364) As Currency
若要设置单个元素的值，您可以指定该元素的索引。 以下示例向该数组中的每个元素均分配一个初始值 20。
Sub FillArray()
Dim curExpense(364) As Currency
Dim intI As Integer
For intI = 0 to 364
curExpense(intI) = 20
Next
End Sub
更改下限
使用模块顶部的 Option Base 语句将第一个元素的默认索引从 0 更改为 1。 在以下示例中， Option Base 语句更改第一个元素的索引， Dim 语句声明具有 365 个元素的数组变量。
Option Base 1
Dim curExpense(365) As Currency
也可以通过使用 To 子句明确设置数组的下限，如以下示例所示。
Dim curExpense(1 To 365) As Currency
Dim strWeekday(7 To 13) As String
在数组中存储 Variant 值
有两种方法可以创建 Variant 值数组。 一种是声明 Variant 数据类型的数组，如以下示例所示：
Dim varData(3) As Variant
varData(0) = "Claudia Bendel"
varData(1) = "4242 Maple Blvd"
varData(2) = 38
varData(3) = Format("06-09-1952", "General Date")
另一种方法是将 Array 函数返回的数组分配给 Variant 变量，如以下示例所示。
Dim varData As Variant
varData = Array("Ron Bendel", "4242 Maple Blvd", 38, _
Format("06-09-1952", "General Date"))
无论使用哪种方法创建数组，均可通过索引识别 Variant 值的数组中的元素。 例如，以下语句可添加到上述两个示例中的任意一个示例中。
MsgBox "Data for " & varData(0) & " has been recorded."
使用多维数组
在 Visual Basic 中，您可以声明最多包含 60 个维度的数组。 例如，以下语句声明了一个二维、5*10 的数组。
Dim sngMulti(1 To 5, 1 To 10) As Single
如果将数组看作矩阵，则第一个参数表示行，第二个参数表示列。
使用嵌套 For...下一个 用于处理多维数组的语句。 以下过程使用 Single 值填充一个二维度组。
Sub FillArrayMulti()
Dim intI As Integer, intJ As Integer
Dim sngMulti(1 To 5, 1 To 10) As Single
' Fill array with values.
For intI = 1 To 5
For intJ = 1 To 10
sngMulti(intI, intJ) = intI * intJ
Debug.Print sngMulti(intI, intJ)
Next intJ
Next intI
End Sub
另请参阅
Visual Basic 概念性主题
支持和反馈
有关于 Office VBA 或本文档的疑问或反馈？ 请参阅 Office VBA 支持和反馈，获取有关如何接收支持和提供反馈的指南。